Módulo de intermitencia para moto con Arduino

Hasta ahora mis experimentos con Arduino eran meros entretenimientos, pero llega un día en que necesitas cierto artilugio y recuerdas tener guardado en un cajón el Arduino que puede darle vida.


Hace unos días noté un comportamiento extraño en mi moto, los intermitentes izquierdos parpadeaban de forma irregular, a veces muy ténue, otras tardaba en empezar... hasta que deduje que la unidad que controla la intermitencia estaba dañada. Seguramente alguna resistencia de carga.

El comportamiento original de la moto era que el intermitente se ponía en marcha mediante un pulsador a cada lado del manillar, y se apagaba al girar o al cabo de un recorrido, dependiendo de la velocidad, información que procede de un encoder dentro del cuenta-km.

Ya desde el principio a mí no me acavaba de gustar el hecho de que se apagara solo al cabo de un recorrido, muchas veces me gusta avisar con tiempo de que voy a salir, y lógicamente tengo que frenar y molesto al resto de vehículos. Y el hecho de que se apagara a los pocos parpadeos, me obligaba a estar pendiente de cuando ocurría y volver a encenderlo.

Buscando por Google vi que en USA se venden unidades "universales" de intermitencia que se pueden adaptar a cualquier moto, y su funcionamiento me gustó: si pulsas 1 segundo, parpadea 7 veces, si pulsas 2 segundos, parpadea 20 veces, y si pulsas 4 segundos parpadea 70 veces. Así que partiendo de esta idea, cogí mi Arduino Uno, le puse dos leds y dos pulsadores y me puse a modelar un programa.

Pero decidí modificar algo el comportamiento. Si pulsas un botón menos de 1 segundo, parpadea 7 veces, si lo pulsas entre 1 y 3 segundos parpadea 20, y si lo pulsas más de 3 segundos parpadea indefinidamente hasta que vuelves a pulsar el mismo botón.

Además mientras está en modo 7 parpadeos o 20 parpadeos, si pulsas el mismo botón se para, y si pulsas el otro, cambia de intermitente y dura el mismo periodo que teníamos seleccionado.

Y para los cuatro intermitentes, pulsando los dos botones a la vez se encienden, y parpadean hasta que pulsas cualquier botón.

La idea la tenía, programarlo ocupó su ratillo pero al final salió un programa que es bastante funcional. Como puerto de entrada para el botón del intermitente derecho utilizo el 3, y el 4 para el izquierdo. La salida para encender y apagar los intermitentes son el puerto 9 y 10 para los derechos e izquierdos, respectivamente.

Os adjunto el código:

/*

Este modesto código pertenece a RosHardware. Se autoriza el uso 
parcial o total del mismo siempre y cuando se indique su procedencia. 

http://www.entremaqueros.com/bitacoras/roshardware

Este programa está diseñado para el funcionamiento de los intermitentes en una moto o coche.
Mediante dos pulsadores, uno para cada lado, activamos o desactivamos los intermitentes. Las salidas
digitales utilizadas sirven para pilotar relés o MOSFETs, que serán los encargados de encender 
y apagar las bombillas.

*/


int pushright=3; //pulsador derecho
int pushleft=4;  //pulsador izquierdo
int turnright=9;  //intermitente derecho
int turnleft=10;  //intermitente izquierdo
unsigned long timebase=0;
unsigned long tright=0; //para guardar el tiempo de pulsación
unsigned long tleft=0;  //para guardar el tiempo de pulsación
int lederror=13; //para casos else
int i=0; //variable bucles

void derecha(int a) //función encender intermitente derecho tiempo 'a'
{
  for(i=1; i<=a; i++)
       {
         digitalWrite(turnright,HIGH);
         delay(300);
         digitalWrite(turnright,LOW);
         if(digitalRead(pushright)==HIGH) //si se pulsa el mismo botón, para
         {
           delay(500);
           break;
         }
         if(digitalRead(pushleft)==HIGH)  //si se pulsa el otro botón cambia de función
         {
           izquierda(a);
           break;           
         }
         delay(400);
         if(digitalRead(pushright)==HIGH) //si se pulsa el mismo botón, para
         {
           delay(500);
           break;
         }
         if(digitalRead(pushleft)==HIGH)  //si se pulsa el otro botón cambia de función
         {
           izquierda(a);
           break;           
         }
       }
}

void izquierda(int a)  //función encender intermitente izquierdo tiempo 'a'
{
   for(i=1; i<=a; i++)
       {
         digitalWrite(turnleft,HIGH);
         delay(300);
         digitalWrite(turnleft,LOW);
          if(digitalRead(pushleft)==HIGH)  //si se pulsa el mismo botón, para
         {
           delay(500);
           break;
         }
         if(digitalRead(pushright)==HIGH)  //si se pulsa el otro botón cambia de función
         {
           derecha(a);
           break;           
         }
         delay(400);
         if(digitalRead(pushleft)==HIGH)  //si se pulsa el mismo botón, para
         {
           delay(500);
           break;
         }
         if(digitalRead(pushright)==HIGH)  //si se pulsa el otro botón cambia de función
         {
           derecha(a);
           break;           
         }
       }
}

void error() //por si no se diera ninguna condición
{
  digitalWrite(lederror, HIGH);
  delay(200);
  digitalWrite(lederror, LOW);
}

void setup()
{
  pinMode(pushright, INPUT);
  pinMode(pushleft, INPUT);
  pinMode(turnright, OUTPUT);
  pinMode(turnleft, OUTPUT);
  pinMode(lederror, OUTPUT);
  //Serial.begin(9600);      // abre el puerto serie a 9600 bps: 
}

void loop()
{
   timebase=millis(); //tiempo de referencia al empezar el bucle
  
  if(digitalRead(pushright)==HIGH && digitalRead(pushleft)==HIGH) // cuatro intermitentes,
                                                                       // para si se pulsa algún botón
  {
    do
    {
      digitalWrite(turnright, HIGH);
      digitalWrite(turnleft, HIGH);
      delay(300);
      if(digitalRead(pushright)==HIGH || digitalRead(pushleft)==HIGH)
      {
        digitalWrite(turnright,LOW);
        digitalWrite(turnleft,LOW);
        delay(500);
        break;
      }
      digitalWrite(turnright, LOW);
      digitalWrite(turnleft, LOW);
      delay(400);
     }while(digitalRead(pushright)==LOW && digitalRead(pushleft)==LOW);
    
    delay(250);
    
  }
   
   else if(digitalRead(pushright)==HIGH && digitalRead(pushleft)==LOW) //si se pulsa el derecho
  {
    delay(20);
    do
    {
      tright=millis(); //tiempo al terminar de pulsar el botón.
    }while(digitalRead(pushright)==HIGH);
    
    tright=tright-timebase; //tiempo pulsando
    //Serial.print(tright);
    //Serial.print( "\n");
    if(tright<=1200)  //si se pulsa aprox 1 segundo
     {
       derecha(7);
     }
     
     else if(tright<=3000)  //si se pulsa aprox 2 segundos
     {
       derecha(20);
     }
     
     else if(tright>3000)  //si se pulsa más de 3 segundos funcionará siempre 
                           //hasta que pulse el mismo botón
     {
        do
        {
        digitalWrite(turnright, HIGH);
        delay(300);
        if(digitalRead(pushright)==HIGH)
        {
          digitalWrite(turnright,LOW);
          delay(300);
          break;
        }
        digitalWrite(turnright, LOW);
        delay(400);
       }while(digitalRead(pushright)==LOW);
    
      delay(500);
     }
     
     else
     {
       error;
     }
  }
  
  else if(digitalRead(pushright)==LOW && digitalRead(pushleft)==HIGH)  //si se pulsa el izquierdo
  {
    delay(20);
    do
    {
      tleft=millis(); //tiempo al terminar de pulsar el botón.
    }while(digitalRead(pushleft)==HIGH);
    
    tleft=tleft-timebase;  //tiempo pulsando
    //Serial.print(tleft);
    //Serial.print( "\n");
    if(tleft<=1200)  //si se pulsa aprox 1 segundo
     {
       izquierda(7);
     }
     
     else if(tleft<=3000)  //si se pulsa aprox 2 segundos
     {
       izquierda(20);
     }
     
     else if(tleft>3000)  //si se pulsa más de 3 segundos funcionará siempre 
                          //hasta que pulse el mismo botón
     {
        do
        {
        digitalWrite(turnleft, HIGH);
        delay(300);
        if(digitalRead(pushleft)==HIGH)
        {
          digitalWrite(turnleft,LOW);
          delay(300);
          break;
        }
        digitalWrite(turnleft, LOW);
        delay(400);
       }while(digitalRead(pushleft)==LOW);
    
      delay(500);
     }
     
     else
     {
       error;
     }
  }
  
    
  else
  {
    digitalWrite(turnright,LOW); //por si a caso
    digitalWrite(turnleft,LOW);  //por si a caso
  }
  
}

Y el fichero listo para cargarlo en la placa Arduino:

intermitentesV8

Una vez escrito el programa faltan dos cosas todavía, reducirlo a la mínima expresión para que ocupe bien poco, y pasar de controlar dos leds con un consumo ridículo a poder manejar unos 50w por canal, puesto que cada bombilla de intermitente consume 21w. Tened en cuenta que el hecho de que pueda manejar consumos de 50W no impide, sinó todo lo contrario, permite controlar intermitentes a leds o cualquier sistema con menor consumo.

Para ello utilizaremos dos MOSFETs P-channel, concretamente los IRF9540, que admiten hasta 100V y 13A, y en nuestro caso trabajaremos a 13.8V y sobre los 5A. Estos MOSFETs necesitan mínimo 10V para operarlos, y al ser P-channel se controlan al revés, al recibir los 10V cortan la salida, y al quitarlos y dejarlo a 0V abren la salida, de modo que añadiendo un transistor BC547 "en serie" entre Arduino y MOSFET conseguiremos dos cosas a la vez, invertir la señal para que cuando Arduino esté en HIGH, encienda los intermitentes, y además elevar la tensión de 5V que saca Arduino a los 13.8V que saca la moto.

Tanto en el puerto 9 como en el 10 añadiremos el siguiente montaje:

Y para los pulsadores recordad que Arduino admite de entrada máximo 5V, de manera que tenemos que mandarle a los botones 5V que podemos sacar del propio Arduino, en vez de los 13.8 que saca la Moto. MUCHO CUIDADO NO OLVIDAR ESTO.

Y para que el montaje final quede compacto, en lugar de un Arduino UNO que es algo grande, he utilizado un Arduino Nano, que podéis encontrar por ebay a partir de 8€

Para alimentar un Arduino Nano se requieren 5V, de modo que añadiendo un 7805 (o un R785.0 en mi caso) conseguimos bajar de 13.8V a 5V fácilmente:

Os adjunto una foto donde he intentado resumir todas las conexiones, espero no haberme dejado nada y que esté suficientemente claro:

He comprado una pequeña caja de aluminio en la tienda de electrónica, le añado un fusible al conjunto de 15A por si las moscas, y el montaje final queda así:


fotos

Antes de que se me olvide, doy las gracias por su ayuda y sus ideas a FXSTC95 de ForoHarley, y a mis compañeros de trabajo Adolf, Martí y Jordi.

Y en estos vídeos podéis ver su funcionamiento, a falta de ser instalado en la moto. Tened en cuenta que es difícil pulsar los pulsadores con una sola mano, estando montados "al aire", además de que son reutilizados y no van muy finos. Solo son para ilustrar el ejemplo:








English translate version.